configure: better CFLAGS checking

configure.ac

@@ -10,6 +10,7 @@ AC_SUBST(MPD_CFLAGS)
 AC_SUBST(MP4FF_LIB)
 AC_SUBST(MP4FF_SUBDIR)
 
+AC_LANG(C)
 AC_PROG_CC
 AM_PROG_CC_C_O
 AC_PROG_INSTALL
@@ -21,8 +22,15 @@ AC_DEFINE(PROTOCOL_VERSION, "0.14.0", [The mpd protocol version])
 
 MPD_LIBS=""
 MPD_CFLAGS=""
-if test x$GCC = xyes; then
-	MPD_CFLAGS="-Wall -Wextra -Wno-unused-parameter -Wno-deprecated-declarations -Wmissing-prototypes"
+if test x$GCC = xyes
+then
+	MPD_CHECK_FLAG([-Wall])
+	MPD_CHECK_FLAG([-Wextra])
+	MPD_CHECK_FLAG([-Wno-unused-parameter])
+	MPD_CHECK_FLAG([-Wno-deprecated-declarations])
+	MPD_CHECK_FLAG([-Wmissing-prototypes])
+	MPD_CHECK_FLAG([-Wdeclaration-after-statement])
+	MPD_CHECK_FLAG([-Wshadow])
 fi
 
 if test -z "$prefix" || test "x$prefix" = xNONE; then

m4/mpd_check_cflag.m4

+AC_DEFUN([MPD_CHECK_FLAG],[
+  var=`echo "$1" | tr "-" "_"`
+  AC_CACHE_CHECK([whether the C compiler accepts $1],
+    [mpd_check_cflag_$var],[
+    save_CFLAGS="$CFLAGS"
+    CFLAGS="$CFLAGS $1"
+    AC_COMPILE_IFELSE([
+     int main(void) { return 0; }
+     ], [ eval "mpd_check_cflag_$var=yes"
+     ], [ eval "mpd_check_cflag_$var=no" ])
+    CFLAGS="$save_CFLAGS"
+  ])
+  if eval "test x`echo '$mpd_check_cflag_'$var` = xyes"
+  then
+    MPD_CFLAGS="$MPD_CFLAGS $1"
+  fi
+  ])
+])